50c63a23e8
* change(android): added android support * change(git): Remove .yarn from version control * change(git): Remove .yarn from version control * change(rn-tracker): android view fixes * change(tracker): yarn * fix rn: fix ios config for react native * ios source changes * change(lib): tracker manager * change(lib): layout fixes * change(lib): layout fixes * fix default api endp --------- Co-authored-by: Shekar Siri <sshekarsiri@gmail.com>
107 lines
2.7 KiB
Groovy
107 lines
2.7 KiB
Groovy
buildscript {
|
|
// Buildscript is evaluated before everything else so we can't use getExtOrDefault
|
|
def kotlin_version = rootProject.ext.has("kotlinVersion") ? rootProject.ext.get("kotlinVersion") : project.properties["ReactNative_kotlinVersion"]
|
|
|
|
repositories {
|
|
google()
|
|
mavenCentral()
|
|
}
|
|
|
|
dependencies {
|
|
classpath "com.android.tools.build:gradle:8.2.2"
|
|
// noinspection DifferentKotlinGradleVersion
|
|
classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
|
|
}
|
|
}
|
|
|
|
def isNewArchitectureEnabled() {
|
|
return rootProject.hasProperty("newArchEnabled") && rootProject.getProperty("newArchEnabled") == "true"
|
|
}
|
|
|
|
apply plugin: "com.android.library"
|
|
apply plugin: "kotlin-android"
|
|
|
|
if (isNewArchitectureEnabled()) {
|
|
apply plugin: "com.facebook.react"
|
|
}
|
|
|
|
def getExtOrDefault(name) {
|
|
return rootProject.ext.has(name) ? rootProject.ext.get(name) : project.properties["ReactNative_" + name]
|
|
}
|
|
|
|
def getExtOrIntegerDefault(name) {
|
|
return rootProject.ext.has(name) ? rootProject.ext.get(name) : (project.properties["ReactNative_" + name]).toInteger()
|
|
}
|
|
|
|
def supportsNamespace() {
|
|
def parsed = com.android.Version.ANDROID_GRADLE_PLUGIN_VERSION.tokenize('.')
|
|
def major = parsed[0].toInteger()
|
|
def minor = parsed[1].toInteger()
|
|
|
|
// Namespace support was added in 7.3.0
|
|
return (major == 7 && minor >= 3) || major >= 8
|
|
}
|
|
|
|
android {
|
|
if (supportsNamespace()) {
|
|
namespace "com.openreplay.reactnative"
|
|
|
|
sourceSets {
|
|
main {
|
|
manifest.srcFile "src/main/AndroidManifestNew.xml"
|
|
}
|
|
}
|
|
}
|
|
|
|
compileSdkVersion getExtOrIntegerDefault("compileSdkVersion")
|
|
|
|
defaultConfig {
|
|
minSdkVersion getExtOrIntegerDefault("minSdkVersion")
|
|
targetSdkVersion getExtOrIntegerDefault("targetSdkVersion")
|
|
|
|
}
|
|
|
|
buildTypes {
|
|
release {
|
|
minifyEnabled false
|
|
}
|
|
}
|
|
|
|
lintOptions {
|
|
disable "GradleCompatible"
|
|
}
|
|
|
|
compileOptions {
|
|
sourceCompatibility JavaVersion.VERSION_1_8
|
|
targetCompatibility JavaVersion.VERSION_1_8
|
|
}
|
|
}
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
google()
|
|
maven { url = uri("https://jitpack.io") }
|
|
}
|
|
|
|
def kotlin_version = getExtOrDefault("kotlinVersion")
|
|
|
|
dependencies {
|
|
// For < 0.71, this will be from the local maven repo
|
|
// For > 0.71, this will be replaced by `com.facebook.react:react-android:$version` by react gradle plugin
|
|
//noinspection GradleDynamicVersion
|
|
implementation("com.facebook.react:react-native:0.20.1")
|
|
implementation("org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version")
|
|
implementation("com.github.shekarsiri:android-tracker:v1.1.4")
|
|
// implementation file("libs/tracker-release.aar")
|
|
}
|
|
|
|
//allprojects {
|
|
// repositories {
|
|
// maven { url = uri("https://jitpack.io") }
|
|
// google()
|
|
// mavenCentral()
|
|
// }
|
|
//}
|
|
|
|
|
|
|